' Excel for Windows. Needs VBA-JSON 2.3.1: import its JsonConverter.bas
' and tick Tools > References > Microsoft Scripting Runtime
Sub FundsList()
    ' Read the list of covered funds (one GET, no key), naming your own project
    Dim http As Object
    ' ServerXMLHTTP does not read the proxy set in Windows: behind a
    ' company proxy, create MSXML2.XMLHTTP.6.0 instead
    Set http = CreateObject("MSXML2.ServerXMLHTTP.6.0")
    http.Open "GET", "https://tickerinside.com/api/v1/funds.json", False
    http.setRequestHeader "User-Agent", "MyProject/1.0 (+https://example.com)"
    http.send
    If http.Status <> 200 Then Err.Raise 513, , "HTTP " & http.Status
    Dim doc As Object
    Set doc = JsonConverter.ParseJson(http.responseText)

    ' A new sheet: how many funds, and the date of the data, on top
    Dim ws As Worksheet
    Set ws = Worksheets.Add
    ws.Range("A1").Value = "funds from issuer files"
    ws.Range("B1").Value = doc("count")
    ws.Range("C1").Value = "as_of"
    ws.Range("D1").Value = doc("as_of")
    ws.Range("A2").Value = "more from SEC filings, listed in sec_funds"
    ws.Range("B2").Value = doc("sec_count")

    ' One row per fund: t is the ticker, n the name
    Dim f As Variant, r As Long
    ws.Columns(1).NumberFormat = "@"
    ws.Range("A4:B4").Value = Array("ticker", "name")
    r = 5
    For Each f In doc("funds")
        ws.Cells(r, 1).Value = f("t")
        ws.Cells(r, 2).Value = f("n")
        r = r + 1
    Next f
End Sub